US3S1L5-2——Phong光照模型的逐片元光照

知识回顾

Phong光照模型公式：

物体表面光照颜色=环境光颜色+兰伯特光照模型所得颜色+Phong式高光反射光照模型所得颜色物体表面光照颜色 = 环境光颜色 + 兰伯特光照模型所得颜色 + Phong式高光反射光照模型所得颜色

其中：

  • 环境光颜色 = UNITY_LIGHTMODEL_AMBIENT​（或者：unity_AmbientSky​、unity_AmbientEquator​、unity_AmbientGround​）
  • 漫反射光颜色 = 兰伯特光照模型 计算得到的颜色
  • 高光反射光颜色 = Phong式高光反射光照模型 计算得到的颜色

利用Phong式光照模型实现光照效果（逐片元光照）

关键步骤：

  1. 计算兰伯特光照模型

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    fixed4 _MainColor;      //属性设置的漫反射颜色

    //计算兰伯特光照模型 颜色相关函数（逐片元）
    //参数：
    //  wNormal: 世界空间下顶点的法线信息
    fixed3 getFragLambertColor(in float3 wNormal)
    {
        float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);  //将光源0的位置标准化，得到方向，用于计算夹角
        //兰伯特光照模型的实现，这里的颜色计算只取rgb，不考虑透明度的情况
        fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(wNormal, lightDir));
        return color;
    }

  2. 计算Phong式高光反射光照模型

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    fixed4 _SpecularColor;  //属性设置的材质高光颜色
    float _SpecularNum;     //属性设置的光泽度

    //计算Phong高光反射光照模型 颜色相关函数（逐片元）
    //参数：
    //  wPos: 世界空间下顶点坐标
    //  wNormal: 世界空间下顶点的法线信息
    fixed3 getFragSpecularColor(in float3 wPos, in float3 wNormal)
    {
        float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - wPos);  //计算观察方向
        float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);          //标准化光源方向
        float3 reflectDir = reflect(-lightDir, wNormal);              //计算反射光线向量，需要对光源方向取反
        //Phong高光反射模型的实现，这里的颜色计算只取rgb，不考虑透明度的情况
        fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
        return color;
    }

完整的Shader代码如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
Shader "TeachShader/Lesson39"
{
    Properties
    {
        _MainColor("MainColor", Color) = (1, 1, 1, 1)           //材质的漫反射颜色
        _SpecularColor("SpecularColor", Color) = (1, 1, 1, 1)   //材质高光反射颜色
        _SpecularNum("SpecularNum", Range(0, 20)) = 0.5         //光泽度
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 svPos : SV_POSITION;     //裁剪空间下的顶点坐标
                float3 wNormal : NORMAL;        //世界空间下的法线
                float3 wPos : TEXCOORD0;        //世界空间下的顶点坐标
            };

            fixed4 _MainColor;      //属性设置的漫反射颜色
            fixed4 _SpecularColor;  //属性设置的材质高光颜色
            float _SpecularNum;     //属性设置的光泽度

            //计算兰伯特光照模型 颜色相关函数（逐片元）
            //参数：
            //  wNormal: 世界空间下顶点的法线信息
            fixed3 getFragLambertColor(in float3 wNormal)
            {
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);  //将光源0的位置标准化，得到方向，用于计算夹角
                //兰伯特光照模型的实现，这里的颜色计算只取rgb，不考虑透明度的情况
                fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(wNormal, lightDir));
                return color;
            }

            //计算Phong高光反射光照模型 颜色相关函数（逐片元）
            //参数：
            //  wPos: 世界空间下顶点坐标
            //  wNormal: 世界空间下顶点的法线信息
            fixed3 getFragSpecularColor(in float3 wPos, in float3 wNormal)
            {
                float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - wPos);  //计算观察方向
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);          //标准化光源方向
                float3 reflectDir = reflect(-lightDir, wNormal);              //计算反射光线向量，需要对光源方向取反
                //Phong高光反射模型的实现，这里的颜色计算只取rgb，不考虑透明度的情况
                fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
                return color;
            }

            v2f vert (appdata_base v)
            {
                v2f v2fData;
                v2fData.svPos = UnityObjectToClipPos(v.vertex);             //顶点转换到裁剪空间
                v2fData.wNormal = UnityObjectToWorldNormal(v.normal);       //法线转换到世界空间
                v2fData.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;      //顶点转换到世界空间
                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //计算Phong式光照模型需要的各种颜色
                fixed3 lambertColor = getFragLambertColor(i.wNormal);                               //计算漫反射
                fixed3 specularColor = getFragSpecularColor(i.wPos, i.wNormal);                     //计算高光反射颜色
                fixed3 phongColor = UNITY_LIGHTMODEL_AMBIENT.rgb + lambertColor + specularColor;    //计算Phong式光照模型颜色
              
                return fixed4(phongColor.rgb, 1);   //因为传递过来的颜色变量不包括透明度，因此这里需要手动指定透明度
            }
            ENDCG
        }
    }
}

显示效果（漫反射颜色为红色，高光反射颜色为白色，光泽度为5，左边为逐片元光照，右边为逐顶点光照）：

​image​

显然，逐片元光照的效果更平滑

‍