US3S1L6-2——Blinn-Phong式高光反射光照模型的逐片元光照

知识回顾

公式：

$$高光反射光照颜色 = 光源的颜色 \times 材质高光反射颜色 \times \max(0,\ \overrightarrow{标准化后顶点法线方向} \cdot \overrightarrow{标准化后半角向量方向})^{光泽度}$$

1. $\overrightarrow{标准化后顶点法线方向} \cdot \overrightarrow{标准化后半角向量方向}$ 得到的结果就是 $\cos\theta$
2. $\overrightarrow{半角向量方向} = \overrightarrow{视角单位向量} + \overrightarrow{入射光单位向量}$
3. 光泽度是幂运算，假设光泽度为 $n$ ，相当于：$(max(0,\cos\theta))^n$

利用Blinn-Phong式高光反射模型实现光照效果（逐片元光照）

关键步骤：基本和逐顶点一致

区别：

1. 在顶点着色器计算顶点和法线相关数据
2. 在片元着色器中计算Blinn-Phong式高光反射光照

Shader实现如下：

Shader "TeachShader/Lesson42"
{
    Properties
    {
        _SpecularColor("SpecularColor", Color) = (1, 1, 1, 1)   //材质高光反射颜色
        _SpecularNum("SpecularNum", Range(0, 20)) = 5           //光泽度
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 svPos : SV_POSITION;     //裁剪空间下的顶点坐标
                float3 wNormal : NORMAL;        //世界空间下的法线
                float3 wPos : TEXCOORD0;        //世界空间下的顶点坐标
            };

            fixed4 _SpecularColor;  //材质高光反射颜色
            float _SpecularNum;     //光泽度

            v2f vert (appdata_base v)
            {
                v2f v2fData;
                v2fData.svPos = UnityObjectToClipPos(v.vertex);             //顶点转换到裁剪空间
                v2fData.wNormal = UnityObjectToWorldNormal(v.normal);       //法线转换到世界空间
                v2fData.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;      //顶点转换到世界空间

                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.wPos);  //将摄像机坐标和顶点坐标通过相减，得到观察方向向量，并标准化
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);          //得到世界空间下的指向光源方向的标准化向量
                float3 halfA = normalize(viewDir + lightDir);                   //将光源方向和观察方向相加得到其半角向量，并标准化
                //Blinn-Phong高光反射模型的实现，这里的颜色计算只取rgb，不考虑透明度的情况
                fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(i.wNormal, halfA)), _SpecularNum);
              
                return fixed4(color.rgb, 1);    //因为传递过来的颜色变量不包括透明度，因此这里需要手动指定透明度
            }
            ENDCG
        }
    }
}

显示效果（光泽度统一为5）：

​​

可见，Blinn-Phong式高光反射模型比Phong式高光反射模型的高光效果更加均匀，面积也更大
而逐片元光照相比逐顶点光照的高光光斑边缘也更加平滑

‍