US5L12——表面着色器使用法线贴图

在表面着色器中使用法线贴图

我们以 SurfaceOutputStandard​ 来举例，步骤如下：

  1. 新建表面着色器

  2. 删除无关代码

  3. 声明相关属性

    1
    2
    3
    4
    5
    6
    Properties
    {
        _Color("Color", Color) = (1, 1, 1, 1)
        _MainTex("Albedo (RGB)", 2D) = "white"{}
        _BumpMap("BumpMap", 2D) = ""{}
    }

  4. 检查编译指令、结构体和变量声明

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    #pragma surface surf Standard fullforwardshadows
    #pragma target 3.0

    sampler2D _MainTex;
    sampler2D _BumpMap;

    struct Input
    {
        float2 uv_MainTex;
        float2 uv_BumpMap;
    };

    fixed4 _Color;

  5. 编写相关逻辑

    将贴图采样结果分别赋值到输出结构体对应的成员变量上即可

    1
    2
    3
    4
    5
    6
    7
    void surf (Input IN, inout SurfaceOutputStandard o)
    {
        fixed4 texColor = tex2D(_MainTex, IN.uv_MainTex);
        o.Albedo = texColor.rgb * _Color.rgb;                       // 漫反射颜色
        o.Alpha = texColor.a * _Color.a;                            // 透明度
        o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));    // 得到切线空间下的法线
    }

显示效果（左为我们自己实现的标准漫反射 Shader，右边为表面着色器实现的 Shader）：

image​

可以看到，在表面着色器中，只需要将纹理采样结果赋值给输出结构体对应的成员上即可实现完整的光照效果，而无需再手写光照和阴影相关逻辑

除了上文使用到的成员变量以外，输出结构体还有几个成员变量还没有赋值这些属性同样可以影响模型在屏幕上的显示效果，
我们可以使用材质的属性在外部对调节这些成员的值以观察它们的显示效果

完整 Shader 代码如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Shader "TeachShader/Lesson139"
{
    Properties
    {
        _Color("Color", Color) = (1, 1, 1, 1)
        _MainTex("Albedo (RGB)", 2D) = "white"{}
        _BumpMap("BumpMap", 2D) = ""{}
        _Emission("Emission", Color) = (0, 0, 0, 0)     // 自发光
        _Metallic("Metallic", Range(0, 1)) = 0          // 金属度
        _Smoothness("Smoothness", Range(0, 1)) = 0      // 光滑度
        _Occlusion("Occlusion", Range(0, 1)) = 1        // 环境光遮蔽
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }

        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows
        #pragma target 3.0

        sampler2D _MainTex;
        sampler2D _BumpMap;
        fixed4 _Emission;
        fixed _Metallic;
        fixed _Smoothness;
        fixed _Occlusion;

        struct Input
        {
            float2 uv_MainTex;
            float2 uv_BumpMap;
        };

        fixed4 _Color;

        void surf (Input IN, inout SurfaceOutputStandard o)
        {
            fixed4 texColor = tex2D(_MainTex, IN.uv_MainTex);
            o.Albedo = texColor.rgb * _Color.rgb;                       // 漫反射颜色
            o.Alpha = texColor.a * _Color.a;                            // 透明度
            o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));    // 得到切线空间下的法线
            o.Emission = _Emission.rgb;                                 // 自发光颜色
            o.Metallic = _Metallic;                                     // 金属度
            o.Smoothness = _Smoothness;                                 // 光滑度
            o.Occlusion = _Occlusion;                                   // 环境光遮蔽
        }
        ENDCG
    }
    FallBack "Diffuse"
}